ネット非対応のテレビドアホンでLINE通知したい

#include <WiFi.h>              //Wi-Fi
#include <WiFiClientSecure.h>  //Wi-Fi
#include <ESPmDNS.h>           //OTA
#include <WiFiUdp.h>           //OTA
#include <ArduinoOTA.h>        //OTA
#define A_SW 13
#define JST 3600 * 9
#define PUSH_SHORT 100

String hostname = "INTPHONE";

boolean button = 0;

// WiFi設定
const char* ssid = "Your SSID";
const char* password = "Your PASSWORD";
IPAddress ip(192, 168, 11, 240);     //ESP32のIPアドレスを固定する場合のアドレス
IPAddress subnet(255, 255, 255, 0);  //ESP32のIPアドレス固定する場合のサブネット
IPAddress gateway(192, 168, 11, 1);  //ルーターのゲートウェイを入れる
IPAddress DNS(192, 168, 11, 1);

bool done = true;

RTC_DATA_ATTR int bootCount = 0;

void setup() {
  pinMode(A_SW, INPUT_PULLUP);
  WiFi.config(ip, gateway, subnet, DNS);
  Serial.begin(115200);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  // WiFi接続
  WiFi.disconnect(true, true);
  WiFi.mode(WIFI_STA);
  WiFi.setHostname(hostname.c_str());
  WiFi.begin(ssid, password);
  while (done) {
    Serial.print("Wi-Fi connecting");
    auto last = millis();
    while (WiFi.status() != WL_CONNECTED && last + 5000 > millis()) {
      delay(500);
      Serial.print(".");
    }
    if (WiFi.status() == WL_CONNECTED) {
      done = false;
    } else {
      Serial.println("Retry");
      WiFi.disconnect(true, true);
      //WiFi.reconnect();
      ESP.restart();
    }
  }
  Serial.println("Wi-Fi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  configTime(JST, 0, "pool.ntp.org", "jp.pool.ntp.org");

  delay(5000);
  send_Line("起動OK!");

  ArduinoOTA
    .onStart([]() {
      String type;
      if (ArduinoOTA.getCommand() == U_FLASH)
        type = "sketch";
      else
        type = "filesystem";

      Serial.println("Start updating " + type);
    })
    .onEnd([]() {
      Serial.println("\nEnd");
    })
    .onProgress([](unsigned int progress, unsigned int total) {
      Serial.printf("Progress: %u%%\r", (progress / (total / 100)));
    })
    .onError([](ota_error_t error) {
      Serial.printf("Error[%u]: ", error);
      if (error == OTA_AUTH_ERROR) Serial.println("Auth Failed");
      else if (error == OTA_BEGIN_ERROR) Serial.println("Begin Failed");
      else if (error == OTA_CONNECT_ERROR) Serial.println("Connect Failed");
      else if (error == OTA_RECEIVE_ERROR) Serial.println("Receive Failed");
      else if (error == OTA_END_ERROR) Serial.println("End Failed");
    });

  ArduinoOTA.begin();

  Serial.println("Ready");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

// Close=0 Open=1
// the loop routine runs over and over again forever:
void loop() {
  ArduinoOTA.handle();
  ///////////////////////
  time_t t;
  struct tm* tm;
  static const char* wd[7] = { "Sun", "Mon", "Tue", "Wed", "Thr", "Fri", "Sat" };
  t = time(NULL);
  tm = localtime(&t);
  /*
  Serial.printf("%04d/%02d/%02d(%s) %02d:%02d:%02d\n",
                tm->tm_year + 1900, tm->tm_mon + 1, tm->tm_mday,
                wd[tm->tm_wday],
                tm->tm_hour, tm->tm_min, tm->tm_sec);
  */


  // 毎日06:05にRestart(ハングアップ対策)
  if ((tm->tm_hour == 06) && (tm->tm_min == 05) && (tm->tm_sec == 00)) {
    ESP.restart();
  }
  unsigned long gauge = 0;
  while (!digitalRead(A_SW)) {
    gauge++;
  }
  if (gauge > PUSH_SHORT) {

    button = !button;
    send_Line("おや?誰か来たよ!");
    delay(60000);
  }
}


// LINE Notify設定
const char* host = "notify-api.line.me";
const char* token = "Your TOKEN";

// LINE通知
void send_Line(String message) {

  // HTTPSへアクセス（SSL通信）するためのライブラリ
  WiFiClientSecure client;

  // サーバー証明書の検証を行わずに接続する場合に必要
  client.setInsecure();

  Serial.println("LINE Connection Try!");

  // LINEのAPIサーバにSSL接続（ポート443:https）
  if (!client.connect(host, 443)) {
    delay(2000);  //2秒
    Serial.println("LINE Connection failed");
    delay(2000);  //2秒
    ESP.restart();
    return;
  }
  Serial.println("LINE Connected Success!");

  // リクエスト送信
  String query = String("message=") + "\n" + message;
  String request = String("") + "POST /api/notify HTTP/1.1\r\n" + "Host: " + host + "\r\n" + "Authorization: Bearer " + token + "\r\n" + "Content-Length: " + String(query.length()) + "\r\n" + "Content-Type: application/x-www-form-urlencoded\r\n\r\n" + query + "\r\n";
  client.print(request);
  delay(5000);  //5秒
  // 受信完了まで待機
  while (client.connected()) {
    String line = client.readStringUntil('\n');
    if (line == "\r") {
      break;
    }
  }
  String line = client.readStringUntil('\n');
}